***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 10, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ2460-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6			level = 3
+  vto = 2.2		 kp = 19.5	)
.model  dds   d(
+   is = 5.491e-12	  n = 1.108			   rs = 2.029e-2
+   eg = 1.043	     trs1 = 2.388e-2)
.model  dbody d(
+   is = 5.491e-12	  n = 1.108			   rs = 2.029e-2
+  cjo = 9.825e-11	  m = 2.981e-1		   vj = 1.324e-1
+   bv = 66			ibv = 250e-6		 tbv1 = 7.615e-4			tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10			level = 1)
.model  dgd   d(
+  cjo = 9.997e-11	  m = 2.866e-1		   vj = 1.018e-1)
.param
+  cgs = 6.500e-10	cgd = 1.000e-10
+   rd = 1.536e-2		 ra = 1.036e-2		  trd = 1.855e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (2.00 , 2.00 ),
+ (3.00 , 3.00 ),
+ (3.40 , 3.33 ),
+ (3.50 , 3.37 ),
+ (3.75 , 3.42 ),
+ (4.00 , 3.46 ),
+ (4.50 , 3.52 ),
+ (5.00 , 3.57 ),
+ (6.00 , 3.67 ),
+ (8.00 , 3.77 ),
+ (10.0 , 3.80 ),
+ (20.0 , 3.83 ),
+ (22.0 , 3.83 ))
egt	  1  2t   value = {3.287e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
